Flash 5 Lab: building a dice game

The dice game sung about in Guys and Dolls can be implemented using Flash and ActionScript. Here is a screen capture after a 'first throw', which was neither a won nor a loss, but defined a point for a follow-up throw.

 ActionScript is code, much like JavaScript, that you write to be invoked by the Flash system at specific times.  ActionScript is either in frames or in event handlers (an event being such a thing as the press and release of a button).  Where the script is located is important.  We recommend two techniques: put all code in a distinct layer, call it actions, above all your graphic content and make the code in the event handlers calls to functions that are defined in the first frame of the main movie, in the actions layer. This does not change when the code is invoked, but will simplify your programming by making the pieces of code easier to find. 

This document is NOT intended to be a cookbook that you follow without thinking.  It should provide you the background you need to build your own version of the dice game and help you to build other projects.  

The first question to ask when planning a project is what features are needed for any particular application?  For this game, here is our list:

1. Code that incorporates logic that constitute the rules of the game.  The rules distinguish between first and follow-up throws.  This means your code must distinguish between these two situations.  In all throws, you [your code] make decisions based on the sum of the number of dots on the two dice.  In a 'first throw', the totals 7 and 11 win; 2, 3 and 12 lose; and anything else means that there must be a follow-up throw.  The total on the first throw becomes 'the point'.  On a follow-up throw, 7 loses and 'the point' wins.  So to create this game, you need a way to define the state of the game ('first or follow-up') and 'the point'.  Think global variables (variables defined with a var statement outside of any function or event handler) and nested if statements.  We will return to this in more detail below.

2. Something that simulates throwing the dice.  We must make the computer produce results that appear random.  This idea should make you nervous because you have learned that computers do not act randomly but are machines that carry out programmed instructions. The correct term for this is pseudo-random.  Flash ActionScript (and other programming languages) have built-in functions that produce results, specifically sequences of numbers that are statistically random.  One approach is to reach into the bit sequence of the internal representation of the time, take the middle bits, do the multiply operation, take the middle bits again, and make this the next number in the sequence.  You do not have to know understand the particular algorithm used.  We will assume that ActionScript is implemented correctly. (This assumption may not be justified.  Software makers have gotten these things wrong.)  What we need specifically for this application is code that will produce a whole number from 1 to 6 such that when it is used over and over, all sequences are equally likely.  The built-in function Math.random() will return a number from zero to 1.  By using this in an expression, we can get a whole number that is one of 1, 2, 3, 4, 5, or 6.
3. An animated sequence that look like jiggling dice.  That is, we would like our dice game to show something like the movement of dice, though we will just make it two-dimensional, not three-dimensional.   It is certainly possible to do something more realistic than what I propose here, but the following seems okay. You will construct 6 distinct graphic symbols for the 6 (flat) die faces.  Then you will construct 6 different movie clips, of varying number of frames (say 12  to 15), with the frames each holding one of the graphics, ending with a specific frame.  This is done using frame-by-frame animation (also known as cel animation). You will name the clips jiggle1, jiggle2, jiggle3, jiggle4, jiggle5, jiggle6.  Actually, the name of the movie clips in the Library does not matter.  You will bring each of these into your main movie, but kept off-stage.  You will name the instances seed1, seed2, seed3, seed4, seed5, seed6.  These instance names are what are important. These names are arbitrary, but you must use a system so that you can write code to refer to specific clips.

4. A way for the player to play, namely simulate a throw of the dice.  You will use a button symbol to do this.  The event handler ( on (release) {  } ) for the release of the button will call a function that does the tasks indicated above: gets the pseudo-random values for two dice, shows the dice jiggling and then stopping with the faces indicating those values, and applying the rules of the game logic.  You could put all this in the event handler itself, but it is better practice to make it a function.  This will be shown below.

5. A way of showing the player text information.  You need a way to indicate if the player has won or lost and also reminding them what 'the point' is.  Flash provides 3 types of text: static, dynamic and input through the Properties panel.  Static text will be used to label portions of the screen. Input text sets up what is called a textbox in other systems for the player to enter text.  Dynamic text is what is required here: you give the text a name and can refer to it in code to set the value or read back what the current setting it.  

6. Synchronizing the dice movement and the text display. It may not be obvious that this could be a problem, but you do not want the text to indicate that the player has won or lost before the dice stop jiggling.  To address this issue, we suggest putting a call to a function to display the information in the last frame of each of the 'jiggle' clips.  

Putting together a Flash project (or a project in any computer system) involves creating the separate parts.  You cannot do everything at once.  It is also often the case that you write one version, test, correct as needed, and then refine and expand.  This is the approach suggested here.  

Begin a new project. Change the name of the first layer to board. Add a new layer and call it actions.  Select the very first frame in the actions layer.  You will put in the code to set up the two global variables to indicate first or follow-up throw and the point value.  You will initialize the firstthrow to be true, since, when we first start it is a first throw.  The point value does not get an initial value. Open up the Actions panel (go to Window/Actions).  Click on the arrow on the upper right and chose Expert mode.  Type in the following:

var  firstthrow = true;

var pointvalue;

var die1; 

var die2;

function throwdice() {

 //something will go in here

}  //ends function
The words following the double slashes are comments.  They are ignored by the Flash system.  They are intended for your benefit.

This sets things up to enter the code for the throwdice function. The throwdice function will be called by the on (release) event handler for a button you will create later.  Notice that it does not take any parameters, as indicated by the opening and closing parenthesis with nothing in-between.  Notice also the opening and closing curly brackets. Even if we did not stop the example to make a comment, it is a good practice to put in the opening and the closing brackets and then go back and put the code in-between.  This lessons the chances of forgetting the closing bracket.  
The function needs to do the following:  generate values for the two dice and apply the logic of the game, using the total of the two die values.  Included in 'applying the logic' is displaying the results.  Applying the logic also involves distinguishing between a first throw and a follow up throw.  The variable firstthrow is defined OUTSIDE of the throwdice function.  This is necessary because its value, true for a first throw and false for a follow up throw, must be maintained between throws.  Similarly, the pointvalue must be maintained between throws.  If it is a first throw, the value of pointvalue has no meaning.  Variables such as firstthrow and pointvalue are called global variables. They are also called state values or state variables because they hold the state of the game. 

Return and put the following 'in' the throwdice function, replacing the //something will go here comment.
Function throwdice () {

  var total;

  outcome = "";

  die1 = 1 + Math.floor(Math.random()*6);

  die2 = 1 + Math.floor(Math.random()*6);

  dievalue1 = die1;

  dievalue2 = die2;

  total = die1 + die2;

  if (firstthrow==true) {

     pointvalued = "";

  
if ( (total==7) || (total == 11) ) 

        { outcome = "You Win"; }

      else {


    if ((total==2)||(total==3) || (total==12)) 

               {outcome = "You Lose";}

        else {firstthrow = false;



        outcome="Need follow up throw";

               pointvalue = total;  } 

           } //ends else for not 7,11 win

   }  //ends if firstthrow

  else {


if (total==pointvalue) {

                outcome = "You Win";

                firstthrow = true;

              }

    else {

             if (total == 7) {

                 outcome = "You Lose";

                 firstthrow = true;

               } // ends if 7 on followup

          } //ends not pointvalue on follow up

   } //ends not firstthrow

} // ends function                                     

Getting the brackets correct requires patience.  Do not expect to get them correct the first time.  Try to match opening and closing.  Flash (unlike HTML/JavaScript) will give you an error message if there are problems with syntax.  They will refer to line numbers. To turn on the display of line numbers, click on the icon at the top right of the action panel showing the arrow pointing diagonally to the top and right.

The code sets the values of the variables die1 and die2.  The two lines invoke the pseudo-random feature twice.  They look the same but will probably return different values.  The function Math.random (technicaly, this is a method of the Math object) returns a number from zero up to but not including 1.  Multiplying this value by 6 results in a value from 0 up to, but not including 6.  Taking the floor means to take the largest integer not bigger than the number.  This will result in either 0, 1, 2, 3, 4, or 5.  Adding 1 results in a number 1, 2, 3, 4, 5 or 6, which is exactly what we want.  The two lines of code will produce values in die1 and die2 for the two dice faces.

Some of this code refers to text fields used to display results to the player.  You have not created them yet!  Setting outcome and pointvalued to empty strings clears out any values from previous play.  You will not notice this most of the time because the execution of code is fast and new values may be the same as the old ones.
So this is the logic without any graphics.  To make it ready for testing, we need to build a way to display results and also create a button that invokes the throwdice function.

Select the first (and only) frame on the board layer: use the text tool (the A) to create a text field.  The properties panel at the bottom of the screen (see the next figure) will give you choices for the type of text field.  Choose Dynamic.  This means that your code will be changing this field.  Enter in the name dievalue1 into the Var field. You also should click to select the outlined box to the left of Var:.  This makes an outline around the text field.  One more thing to do or confirm.  The color of the text is indicated by the box to the left of the B for bold.  Make sure this is a color that is legible, that is, not white against a white background.

Repeat, giving the second field the name dievalue2.  These fields will be used to show the results of a dice throw that is done using the random function.  Create a third text field of type Dynamic and give it the name outcome.  Create another Dynamic field and give it the name pointvalued. You will use these fields to send information to the player.  

Now create a button symbol, with text on it: Throw dice. You do this by clicking on Insert on the top toolbar and selecting New Symbol.  Type in a name for the symbol (throw would be okay) and select type Button from the choices: Movie Clip, Button, Graphic.  You are taken to a new time line and stage.  Create the button.  A button has 4 keyframes. You need to insert all but the first using the Insert menu. You can make these different, but it is okay to just use what you create for the first keyframe.  

Return to Scene 1 (the main movie).    Create an instance of this symbol in the first frame of the board layer of the main movie timeline.  To do this, you may need to go to Window/Library to make the Library panel appear.  The Library panel holds all the symbols you have created.  In this case, you just have the one throw button.  You create an instance of the symbol in the main movie by selecting and then dragging the symbol to the stage.  

Make sure the button is selected. In the Action panel, enter:


on (release) {



throwdice()


}

Test the new program. All you need to do now is click on the button.

NOTE: you could put all the code that is in the throwdice function instead in the on (release) definition.  Using functions means you can put all the code in one place. 

Now we need to work on the graphics for the game.  I leave most of that to you: first make the 6 graphics for the 6 die faces as Insert/New Symbol. Then make the jiggle movie clips.  That is, make a movie clip with a sequence of frames each showing a different die face in a slightly different position, with the last frame showing a specific die face.  You do this by using Insert/Blank Keyframe to make the new frames and bringing in one of the graphic symbols.  Name what I am calling the jiggle movie clips seed1, seed2, seed3, seed4, seed5 and seed6.  The movie clip named seed1 will end with the die face graphic face1.

 In each clip, create a new layer and call it actions.  In the first frame of the actions layer of each clip, put it the single line:


_root.clearvalues();

In the last frame of each clip (make sure it is a keyframe), put in the code:

     _root.setvalues();
     stop();
These are functions that we will write later in the first frame, actions layer of the main movie.  They clear away and set, respectively, the visible text fields.  The functions are defined in the _root (main) movie.
To return to the main movie, if the Scene 1 does not appear, you can go to the Edit pull down menu and click on Edit Documents.

Finally, make instances of each of the movie clips by clicking on each one and moving it to off stage.  Give the instances the names seed1, seed2, etc.  The name 'seed' is meant to be evocative of the use. We use these as seeds from which to produce what we need on-stage.  The code removes any instances already created; makes copies of the seeds using the randomly generated functions, and moves those copies to the stage to a randomly determined position.

The function used is duplicateMovieClip.  It takes 3 parameters: the first is the name of the clip to be duplicated.  In our case, it will be one of the seed clips.  The second is the name this new clip is to have.  We have one for each die: we will call them moving1 and moving2.  The last parameter indicates depth.  When we create new movie clips, we can have one at each depth, so we will use 1 and 2.   Change the first part of throwdice to the following: (add the var statements for die1name and die2name, leave the calls to random alone, and add the code that follows).

      var die1name;

   var die2name;

   die1 = 1 + Math.floor(Math.random()*6);

   die2 = 1 + Math.floor(Math.random()*6);

   removeMovieClip (moving1);

   removeMovieClip (moving2 );

   die1name = "seed" + die1;

   die2name = "seed" + die2;

   duplicateMovieClip(die1name,"moving1",1);

   moving1._x = 50;

   moving1._y = 70 + 10* random(10);

   moving1._rotation = random(80);

   duplicateMovieClip(die2name,"moving2",2);

   moving2._x = 200;

   moving2._y = 200 - 10* random(10);

   moving2._rotation = random(80);
   movingdice = 2;
   moving1.gotoAndPlay(1);
   moving2.gotoAndPlay(1);

This creates two new movie clips, positions and rotates each based on pseudo-random values and then starts both of them.  Add the global variable (above the definition of throwdice) for movingdice.
var movingdice;

Go to the text fields and change the names to outcomed, pointvalued, dievalue1d and dievalue2d.  The d at the end is to remind us that these are the displayed values in contrast to the internal variables.  The challenge is to coordinate displaying the text data with the completion of the jiggling clips. You don't want the results to be displayed before the dice finish jiggling. So we need different internal and external names and we also need to have certain of these variables be global, that is, defined outside of any functions.  Go to the first frame of the actions layer of the first movie. You will now define two new functions, so make sure you are writing outside of the throwdice function.  The clearvalues function clears out (sets to the empty string) die1valued, die2valued and outcomed every time.  If it is a first throw, it also clears out pointvalued.  The setvalues function sets those values.

function clearvalues() {

if (_root.firstthrow) {

  _root.pointvalued = "";

}

  _root.dievalue1d ="";

  _root.dievalue2d = "";

  _root.outcomed = "";

}

function setvalues() {
  _root.movingdice = _root.movingdice -1;

  if (_root.movingdice==0) {
  _root.dievalue1d = _root.die1;

  _root.dievalue2d = _root.die2;

  _root.pointvalued = _root.pointvalue;

  _root.outcomed = _root.outcome;

  }
}

The setvalues function is called when each jiggle clip finishes. How do we know when they have both stopped?  The code in throwdice sets the variable movingdice to 2. Within the setvalues function, the global variable movingdice gets decremented by 1. When it is zero—when it has been bumped down twice indicating both dice have stopped jiggling, the code sets the Dynamic text fields giving the player the results of the throw.

Here is the final set of var statements for the global variables and the definition of thowdice function  Notice what has changed and what is the same from how you started.

var  firstthrow = true;

var die1; 

var die2;

var movingdice;

var pointvalue;

var outcome;

function throwdice() {

  var total;

  var die1name;

  var die2name;

   die1 = 1 + Math.floor(Math.random()*6);

   die2 = 1 + Math.floor(Math.random()*6);

   removeMovieClip ("moving1");

   removeMovieClip ("moving2");

   die1name = "seed" + die1;

   die2name = "seed" + die2;

   duplicateMovieClip(die1name,"moving1",1);

   moving1._x = 50;

   moving1._y = 70 + 10* random(10);

   moving1._rotation = random(80);

   duplicateMovieClip(die2name,"moving2",2);

   moving2._x = 200;

   moving2._y = 200 - 10* random(10);

   moving2._rotation = random(80);

   movingdice = 2;

   moving1.gotoAndPlay(1);

   moving2.gotoAndPlay(1);

      total = die1 + die2;


  trace("die1 is "+die1+ " die2 "+die2);

 if (firstthrow==true) {

     pointvalue = "";

  
if ( (total==7) || (total == 11) ) 

        { outcome = "You Win"; }

      else {


    if ((total==2)||(total==3) || (total==12)) 

               {outcome = "You Lose";}

        else {firstthrow = false;



        outcome="Need follow up throw";

               pointvalue = total;  } 

           } //ends else for not 7,11 win

 }  //ends if firstthrow

 else {


if (total==pointvalue) {

                outcome = "You Win";

                firstthrow = true;

              }

    else {

             if (total == 7) {

                 outcome = "You Lose";

                 firstthrow = true;

               } // ends if 7 on followup

          } //ends not pointvalue on follow up

         } //ends not firstthrow

    } // ends function

Summary:  the final project consists of a main movie clip made up of one frame with two layers.  

· The content in the first layer, named board, includes the dynamic text fields die1valued, die2valued, outcomed, and pointvalued plus one static text field.  You may choose to put more (and better) graphics. In addition, instances of 6 movie clips named seed1, seed2, seed3, seed4, seed5, and seed6 are present but off-stage.  The layer also includes one button.

· The second layer, called actions, holds declarations of variables and function definitions.  The variables are defined (set up by var statements) outside of functions because they must retain their value after the functions end. The throwdice function is invoked by the on (release) event handler for the button.  The next two functions are invoked by code in the actions layer of the movie clip duplicates of the clips representing jiggling dice.

